Le code 128.

• The width of a slim bar is named the module.
• There are bars of 1, 2, 3 or 4 modules; equally for the spaces.
• There are 107 patterns, each is coded with 11 modules including 3 bars and 3 spaces (The STOP pattern have 4 bars).
• There are 3 tables giving the character or the function affected to each pattern.
  • Table A contains the capital letters, the digits, the punctuations, some control codes and special codes.
  • Table B contains capital and lower case letters, the digits, the punctuations and special codes.
  • Table C contains pairs of digits (Allowing to double the density) and special codes.
• White zones of at least 10 modules are requested on the left and on the right.
• There is a START character at the beginning of the code. There are 3 START characters fixing the table used for the start.
• The code ends with a STOP character.
• Some special characters (99, 100 & 101) make it possible to pass from one table to an other; the SHIFT character (98) switch the next character between tables A & B.
• The function codes (FNC1 a FNC4) aren't all defined.
• A checksum must be added; its value is calculated by adding up the value of the START then the value of each pattern multiplied by its row; then by taking the remainder of the division of this sum by 103.
• In the following array a bar module is symbolized by "1" and a space module by "0".
• The columns "ASCII Code" and "Character" indicate the place of the patterns in the font "code128.ttf" (See further)
• The character number 0 (Space) is obtained with the code 32 or with the code 212 because some programming tools cannot use code 32.

Example of checksum with use of table B for : ZB65
104 + (1 x 58) + (2 x 34) + (3 x 22) + (4 x 21) = 380
380 / 103 = 3, remainder 71 which is the value of the key.

• The graphic method where each bar is "drawn" as a full rectangle. This method enable to compute the width of each bar with a one pixel precision and so we can work with widths which are perfect multiple of the used device pixel. This give us a good accuracy specially if the device have a low density as it's the case with screens and inkjet printers. This method require special programming routines and does not allow to make bar codes with a current software.
• The special font in which each character is replaced by a bar code. This method allow the use of any software like a text processing or a spreadsheet. (For example LibreOffice, the free clone of MSoffice !) The scale settings according to the selected size can bring away small misshaping of the bar drawing. With a laser printer there's no probs.

Copy this file in the font directory, often named : \Windows\Fonts

• One of the three START code, generally START B.
• As many characters as necessary, special codes makes it possible to pass from one table to an other. An intelligent algorithm will allow to use one or more tables giving the barcode shortest possible.
• A checksum.
• A STOP code.

Note optimization of "3754" to "EV" of the table C

Here is a small program written with Visual Basic 6 ; The
setup file copy the program, Visual Basic
dependencies, source files and the font.

Setup file :

ZIP file without setup :

This test program does not manage the ASCII control codes, it use the tables B & C with optimization length of the code obtained.

Public Function Code128$(chaine$)
  'V 2.0.0
  'Paramètres : une chaine
  'Parameters : a string
  'Retour : * une chaine qui, affichée avec la police CODE128.TTF, donne le code barre
  '         * une chaine vide si paramètre fourni incorrect
  'Return : * a string which give the bar code when it is dispayed with CODE128.TTF font
  '         * an empty string if the supplied parameter is no good
  Dim i%, checksum&, mini%, dummy%, tableB As Boolean
  Code128$ = ""
  If Len(chaine$) > 0 Then
  'Vérifier si caractères valides
  'Check for valid characters
    For i% = 1 To Len(chaine$)
      Select Case Asc(Mid$(chaine$, i%, 1))
      Case 32 To 126, 203
      Case Else
        i% = 0
        Exit For
      End Select
    Next
    'Calculer la chaine de code en optimisant l'usage des tables B et C
    'Calculation of the code string with optimized use of tables B and C
    Code128$ = ""
    tableB = True
    If i% > 0 Then
      i% = 1 'i% devient l'index sur la chaine / i% become the string index
      Do While i% <= Len(chaine$)
        If tableB Then
          'Voir si intéressant de passer en table C / See if interesting to switch to table C
          'Oui pour 4 chiffres au début ou à la fin, sinon pour 6 chiffres / yes for 4 digits at start or end, else if 6 digits
          mini% = IIf(i% = 1 Or i% + 3 = Len(chaine$), 4, 6)
          GoSub testnum
          If mini% < 0 Then 'Choix table C / Choice of table C
            If i% = 1 Then 'Débuter sur table C / Starting with table C
              Code128$ = Chr$(210)
            Else 'Commuter sur table C / Switch to table C
              Code128$ = Code128$ & Chr$(204)
            End If
            tableB = False
          Else
            If i% = 1 Then Code128$ = Chr$(209) 'Débuter sur table B / Starting with table B
          End If
        End If
        If Not tableB Then
          'On est sur la table C, essayer de traiter 2 chiffres / We are on table C, try to process 2 digits
          mini% = 2
          GoSub testnum
          If mini% < 0 Then 'OK pour 2 chiffres, les traiter / OK for 2 digits, process it
            dummy% = Val(Mid$(chaine$, i%, 2))
            dummy% = IIf(dummy% < 95, dummy% + 32, dummy% + 105)
            Code128$ = Code128$ & Chr$(dummy%)
            i% = i% + 2
          Else 'On n'a pas 2 chiffres, repasser en table B / We haven't 2 digits, switch to table B
            Code128$ = Code128$ & Chr$(205)
            tableB = True
          End If
        End If
        If tableB Then
          'Traiter 1 caractère en table B / Process 1 digit with table B
          Code128$ = Code128$ & Mid$(chaine$, i%, 1)
          i% = i% + 1
        End If
      Loop
      'Calcul de la clé de contrôle / Calculation of the checksum
      For i% = 1 To Len(Code128$)
        dummy% = Asc(Mid$(Code128$, i%, 1))
        dummy% = IIf(dummy% < 127, dummy% - 32, dummy% - 105)
        If i% = 1 Then checksum& = dummy%
        checksum& = (checksum& + (i% - 1) * dummy%) Mod 103
      Next
      'Calcul du code ASCII de la clé / Calculation of the checksum ASCII code
      checksum& = IIf(checksum& < 95, checksum& + 32, checksum& + 105)
      'Ajout de la clé et du STOP / Add the checksum and the STOP
      Code128$ = Code128$ & Chr$(checksum&) & Chr$(211)
    End If
  End If
  Exit Function
testnum:
  'si les mini% caractères à partir de i% sont numériques, alors mini%=0
  'if the mini% characters from i% are numeric, then mini%=0
  mini% = mini% - 1
  If i% + mini% <= Len(chaine$) Then
    Do While mini% >= 0
      If Asc(Mid$(chaine$, i% + mini%, 1)) < 48 Or Asc(Mid$(chaine$, i% + mini%, 1)) > 57 Then Exit Do
      mini% = mini% - 1
    Loop
  End If
Return
End Function
			

Excel sample file

Libre Office sample file

Language Author   WinDev 5.5 Laurent PERICAUD L4G Progress André SEJOURNET Visual Foxpro Emile MAITREJEAN Delphi Jean-Camille POPULUS Delphi Francisco FERNANDEZ PL/SQL pour Oracle Nicolas FANCHAMPS PLpgSQL Nicolas FANCHAMPS Crystal Report Sébastien REZÉ Python Michel CLAVEAU Java Virginie LHUILLIER Java Jean-Luc BLOECHLE ASP G!L PHP F. Odouard & P. Guizard C # Joffrey VERDIER

The EAN.UCC 128 codes.

These are codes 128 whose content is standardized and correspond to a use in the field of logistic. An EAN128 code starts with the Fnc1 character followed by one or several fields of data. Each field starts with an AI (Application Identifier) which announce the field content (Number of parcel or durability date for examples) followed by the data themselves. These datas are length fixed or variable, numerical or alphanumeric, with or without checksum and all this according to each AI.
If a field is with variable length, that the maximum length isn't used and that it is not the last field, then it must be followed by a Fnc1 character. Some AI requires that the datas are followed by a checksum; this one is computed in the following way :

• The digits are numbered from right to left, then we compute x the sum of even digits and y the sum of odd digits.
• Let's calculate z = x + 3 * y
• Let m be the number divisible by 10 immediately superior to z
• The checksum is : m - z

I have written a small program allowing to create easily EAN128 codes and holding account of these characteristics.

Setup file

ZIP file wihout setup