• The first digit is not coded but it determines the tables to be used for coding the following 6 digits.
• The width of a thin bar (0.33 mm standard) is called the module.
• There are bars of 1, 2, 3 or 4 modules; the same applies to spaces.
• Each number is coded on 7 modules, each comprising 2 bars and two spaces.

• The start and end markers are : «101»
• The separator mark placed in the middle after the 7th digit is : «01010»
• The total length is always 12 * 7 + 2 * 3 + 5 = 95 modules ; there are always 30 bars in total.
• The separator bars are 5 modules longer than the other bars.
• You need white margins of at least 11 modules on the left and 7 modules on the right.

The first digit is not coded; each of the following six digits is converted using either Table A or Table B, depending on the first digit. The last six digits are converted using Table C.
A new table indicates whether Table A or B was used, depending on the first digit.

Since we can create the barcode pattern it remains us to draw it on the screen and to print it on a paper sheet. Two approaches are possibles :

• The graphic method where each bar is "drawn" as a full rectangle. This method enable to compute the width of each bar with a one pixel precision and so we can work with widths which are perfect multiple of the used device pixel. This give us a good accuracy specially if the device have a low density as it's the case with screens and inkjet printers. This method require special programming routines and does not allow to make bar codes with a current software.
• The special font in which each character is replaced by a barcode. This method allow the use of any software like a text processing or a spreadsheet. (For example LibreOffice, the free clone of MSoffice !) The scale settings according to the selected size can bring away small misshaping of the bar drawing. With a laser printer there's no probs.

Most fonts for EAN barcodes found on the net (incomplete demo fonts) are paid (sometimes very expensive) and of questionable quality ; width of the modules is not always constant in the definition of the font. So I decided to completely design an EAN13 font and offer it in download. I tested it on a 14 body laser printer, which gives a very small barcode of around 13mm wide, result: 100% reading! On a good inkjet printer, this same body of 14 works perfectly.

This font contain the 5 sets of the 10 digits for the 3 tables A, B and C learned above and 2 tables for the first digit (Table D & E)

• Table A : Set of code A with the digit under the barcode.
• Table B : Set of code B with the digit under the barcode.
• Table C : Set of code C with the digit under the barcode.
• Table D : Set of digits with the start delimiter
• Table E : Set of digits without the start delimiter (Requested for the SAGE softwares)

The following table indicates the correspondence between the drawned bar code and the typed letter (ASCII code between bracket)

Copy this file in the font directory, often named : : \Windows\Fonts

• Digit number 1 from table D (Left quiet zone and start delimiter included)
• 6 digits from tables A or B according to the first digit
• Middle delimiter
• 6 digits from table C
• End delimiter (Right quiet zone included)

Here is a small program written with Visual Basic 6.
The setup file copy the program, the Visual Basic
dependencies, the source files and the font.

Setup file :

ZIP file without setup :

Public Function ean13$(chaine$)
  'Cette fonction est régie par la Licence Générale Publique Amoindrie GNU (GNU LGPL)
  'This function is governed by the GNU Lesser General Public License (GNU LGPL)
  'V 1.1.1
  'Paramètres : une chaine de 12 chiffres
  'Parameters : a 12 digits length string
  'Retour : * une chaine qui, affichée avec la police EAN13.TTF, donne le code barre
  ' * une chaine vide si paramètre fourni incorrect
  'Return : * a string which give the bar code when it is dispayed with EAN13.TTF font
  ' * an empty string if the supplied parameter is no good
  Dim i%, checksum%, first%, CodeBarre$, tableA As Boolean
  ean13$ = ""
  'Vérifier qu'il y a 12 caractères
  'Check for 12 characters
  If Len(chaine$) = 12 Then
    'Et que ce sont bien des chiffres
    'And they are really digits
    For i% = 1 To 12
      If Asc(Mid$(chaine$, i%, 1)) < 48 Or Asc(Mid$(chaine$, i%, 1)) > 57 Then
i% = 0
Exit For
      End If
    Next
    If i% = 13 Then
      'Calcul de la clé de contrôle
      'Calculation of the checksum
      For i% = 12 To 1 Step -2
checksum% = checksum% + Val(Mid$(chaine$, i%, 1))
      Next
      checksum% = checksum% * 3
      For i% = 11 To 1 Step -2
checksum% = checksum% + Val(Mid$(chaine$, i%, 1))
      Next
      chaine$ = chaine$ & (10 - checksum% Mod 10) Mod 10
      'Le premier chiffre est pris tel quel, le deuxième vient de la table A
      'The first digit is taken just as it is, the second one come from table A
      CodeBarre$ = Left$(chaine$, 1) & Chr$(65 + Val(Mid$(chaine$, 2, 1)))
      first% = Val(Left$(chaine$, 1))
      For i% = 3 To 7
tableA = False
 Select Case i%
 Case 3
   Select Case first%
   Case 0 To 3
     tableA = True
   End Select
 Case 4
   Select Case first%
   Case 0, 4, 7, 8
     tableA = True
   End Select
 Case 5
   Select Case first%
   Case 0, 1, 4, 5, 9
     tableA = True
   End Select
 Case 6
   Select Case first%
   Case 0, 2, 5, 6, 7
     tableA = True
   End Select
 Case 7
   Select Case first%
   Case 0, 3, 6, 8, 9
     tableA = True
   End Select
 End Select
       If tableA Then
 CodeBarre$ = CodeBarre$ & Chr$(65 + Val(Mid$(chaine$, i%, 1)))
       Else
 CodeBarre$ = CodeBarre$ & Chr$(75 + Val(Mid$(chaine$, i%, 1)))
       End If
     Next
      CodeBarre$ = CodeBarre$ & "*"   'Ajout séparateur central / Add middle separator
      For i% = 8 To 13
CodeBarre$ = CodeBarre$ & Chr$(97 + Val(Mid$(chaine$, i%, 1)))
      Next
      CodeBarre$ = CodeBarre$ & "+"   'Ajout de la marque de fin / Add end mark
      ean13$ = CodeBarre$
    End If
  End If
End Function
			

Demo Excel file

File for Libre Office

Since the first publication of this page, I have received numerous versions in different languages; here they are :

Language Author   Neobook 4 Jean-Louis HUVE Visual Foxpro Emile MAITREJEAN Delphi John SWIJSEN Delphi YARDIMLI EKIM E YARDIMLI Delphi Francisco FERNANDEZ C# Russell SAYERS Perl Simone FIORAVANTI Axapta Søe JESPER

The EAN 8 code

It closely resembles the EAN 13 code. It consists of 7 digits and a checksum calculated in exactly the same way as for the EAN13 code. The left (ASCII 58 will be used), middle, and right delimiters are the same. The first 4 digits are constructed using table A and the last 4 using table C.
We will therefore also use the EAN13 font with this function :

Public Function EAN8$(chaine$)
  'V 1.0.0
  'Paramètres : une chaine de 7 chiffres
  'Parameters : a 7 digits length string
  'Retour : * une chaine qui, affichée avec la police EAN13.TTF, donne le code barre
  ' * une chaine vide si paramètre fourni incorrect
  'Return : * a string which give the bar code when it is dispayed with EAN13.TTF font
  ' * an empty string if the supplied parameter is no good
  Dim i%, checksum%, first%, CodeBarre$, tableA As Boolean
  EAN8$ = ""
  'Vérifier qu'il y a 7 caractères
  'Check for 7 characters
  If Len(chaine$) = 7 Then
    'Et que ce sont bien des chiffres
    'And they are really digits
    For i% = 1 To 7
      If Asc(Mid$(chaine$, i%, 1)) < 48 Or Asc(Mid$(chaine$, i%, 1)) > 57 Then
i% = 0
Exit For
      End If
    Next
    If i% = 8 Then
      'Calcul de la clé de contrôle
      'Calculation of the checksum
      For i% = 7 To 1 Step -2
checksum% = checksum% + Val(Mid$(chaine$, i%, 1))
      Next
      checksum% = checksum% * 3
      For i% = 6 To 1 Step -2
checksum% = checksum% + Val(Mid$(chaine$, i%, 1))
      Next
      chaine$ = chaine$ & (10 - checksum% Mod 10) Mod 10
      'Les 4 premier chiffre viennent de la table A
      'The first 4 digits come from table A
      CodeBarre$ = ""   'Ajout marque de début / Add start mark
      For i% = 1 To 4
 CodeBarre$ = CodeBarre$ & Chr$(65 + Val(Mid$(chaine$, i%, 1)))
      Next
      CodeBarre$ = CodeBarre$ & "*"   'Ajout séparateur central / Add middle separator
      For i% = 5 To 8
CodeBarre$ = CodeBarre$ & Chr$(97 + Val(Mid$(chaine$, i%, 1)))
      Next
      CodeBarre$ = CodeBarre$ & "+"   'Ajout de la marque de fin / Add end mark
      EAN8$ = CodeBarre$
    End If
  End If
End Function